エラーが発生しています。

セーブデータ永続化のテスト

by mj, at 2015年7月25日 21:01:47

powered by hsp3dish.js / OpenHSP

コメント
説明

/save/以下に保存したファイルはブラウザ上に保存することができます.

このプログラムを開き,適当な場所をクリックした後,ブラウザの更新ボタンを押して,もう一度実行してみてください.

先ほどクリックした座標が記憶されていると思います.


ソースコード

ファイルを保存した後,devcontrol "syncfs"を呼び出す必要があります.

#include "hsp3dish.as"

	// 初期化
	screen 0, 640, 480
	
	// 丸が表示される位置
	x = -1: y = -1
	
	// セーブデータが存在するか
	exist "/save/touched"
	
	if (strsize > 0) {
		// 読み込み,コンマで分割しx, yへ設定
		buf = ""
		bload "/save/touched", buf
		
		split buf, ",", sx, sy
		x = int(sx): y = int(sy)
	}

*main

	// 画面の書き換えを止める
	redraw 0
	
	// クリックされた場合setに飛ぶ
	stick key
	if (key & 256) : gosub *set

	// 画面全体を(0, 0, 32)の色で塗りつぶす
	color 0, 0, 32
	boxf
	
	// メッセージを表示,または丸を表示
	color 255, 255, 255
	pos 10, 10
	if (x < 0 && y < 0) {
	
		mes "好きな場所をクリックしてください"
		
	} else {
	
		mes "あなたがクリックした場所は..."
		circle x -10, y -10, x +10, y +10
		pos x -20, y -30
		mes "ここです"
		
	}

	// 画面の書き換えを反映
	redraw 1
	
	// 33ミリ秒待つ
	await 33

	// *mainまで戻る
	goto *main

*set
	// 丸の位置を設定
	x = mousex: y = mousey
	
	// コンマで区切り,座標を保存
	buf = "" + x + "," + y
	bsave "/save/touched", buf
	
	// 同期
	devcontrol "syncfs"
return

作成者
icon

mj

ここはユーザの紹介文

詳しく...


関連プログラム